uso de spice. - ramos departamento de...

1

Leopoldo Silva Bijit 27-06-2008

Apéndice 1

Uso de SPICE en la simulación de redes

A1.1 Introducción

La simulación es una poderosa herramienta para resolver problemas de diseño. Los

simuladores no reemplazan el trabajo de laboratorio con componentes reales e instrumentos,

pero si permiten preparar las experiencias y aprovechar mejor el tiempo dedicado a la práctica

de laboratorio.

El lenguaje fue desarrollado en la Universidad de Berkeley, para predecir las características

eléctricas de dispositivos electrónicos y eléctricos.

En la actualidad es un estándar en la industria, los fabricantes de dispositivos suelen

entregar, además de la hoja de datos, el modelo SPICE que lo representa. La mayoría de los

programas comerciales funcionan basados en las ideas y algoritmos de SPICE.

Es difícil concebir una universidad dedicada a la enseñanza de la electrónica que no utilice

SPICE, o sus derivados, en sus asignaturas. Por esta razón existen numerosos sitios con cursos

basados en SPICE, tutoriales, textos, modelos de componentes, ejemplos de diseño,

laboratorios, etc.

Si se busca en la red “spice”, se encontrarán sitios de descarga, existen versiones para Unix,

Linux y Windows.

Una vez obtenida e instalada alguna versión estudiantil o libre de SPICE, podrán realizarse

los ejercicios que se desarrollan en este apéndice.

Los ejemplos se desarrollan en base a la descripción de la red, del modo de simulación y de

los resultados que deseen obtenerse mediante archivos de texto, a los cuales se les coloca

extensión .cir.

La principal ventaja de introducirse en SPICE, mediante su lenguaje de comandos, además

de la rapidez con que se pueden ingresar diseños y circuitos pequeños, es que permite

familiarizarse con las capacidades básicas del lenguaje: Sus modos de análisis, la generación de

resultados, la descripción de las componentes.

Es posible ingresar la red mediante el diseño de esquemáticos, en un ambiente visual. Esta

actividad se verá facilitada si previamente se conocen las capacidades básicas del lenguaje, ya

que este conocimiento orienta la navegación.

2 Teoría de Redes Eléctricas


SPICE realiza varios tipos de análisis, los más importantes son:

Cálculo del punto de operación, análisis con excitaciones continuas de redes no lineales,

cálculo de la característica de transferencia con excitaciones continuas.

Análisis transitorio de redes no lineales con diversos estímulos, cálculo del espectro de

Fourier.

Análisis de redes lineales con excitaciones sinusoidales en estado estacionario y cálculo de la

respuesta en frecuencia.

Además efectúa análisis de ruido, análisis paramétrico y de Monte Carlo.

También efectúa simulaciones de componentes digitales y permite el análisis de redes

mixtas: análogas y digitales.

A1.2. Análisis continuo o DC. .OP .DC

En la red de la Figura A1.1, se ilustran los convenios para definir variables que se emplean

en SPICE. Los nodos pueden identificarse por números, el nodo de referencia se marca con el

número 0.

Figura A1.1 Convenios SPICE

La descripción de la red se efectúa colocando al comienzo de una línea el tipo de

componente. Las fuentes de voltaje independiente comienzan con V, las de corriente con I, y las

resistencias con R.

Un asterisco al comienzo de una línea indica que ésta es un comentario. Puede colocarse un

comentario de fin de línea mediante el separador punto y coma.

En la primera línea, obligatoria, se suele colocar una breve descripción de la red.

Luego del tipo de componente se colocan el nodo inicial y el final, después el valor del

parámetro, suelen emplearse abreviaciones para las unidades.

Abreviaturas para las unidades.

2 1

0

V1

R1

I2 R2

I(R2) I(V1)

V(2)

Apéndice 1. Uso de SPICE 3


T = 1012

G = 109 Meg = 10

6 K =

103

m = 10-3

u = 10-6

n = 10-9

p = 10-12

f =

10-15

El orden de los nodos define la polaridad del voltaje o la dirección de la corriente.

El archivo debe terminarse con el comando .END, y luego debe colocarse un retorno.

La red se carga abriendo la pestaña File; con la opción open se selecciona el archivo. Luego

se ejecuta en Simulation la opción Run. En una ventana de compilación se muestran los pasos

realizados; luego de que el programa corra libre de errores, se pueden abrir los archivos con

extensión cir y con extensión out. En éste último aparecen los resultados de la simulación.

También pueden generarse formas de ondas de las variables, para tener una visualización de los

resultados; mediante el comando probe se generan archivos con extensión .dat.

El siguiente es el texto que describe la red de la Figura A1.1, el tipo de simulación y los

resultados que desean generarse. Se han agregado comentarios para describir los comandos.

Programa

Red simple

*Descripción de la red.

V1 1 0 DC 10.0V ; Polaridad de 1 a 0

R1 1 2 5.0 ;

R2 2 0 4.0

I2 0 2 DC 2.0A ; Dirección de 0 a 2

*Para imprimir tablas usando PRINT es preciso efectuar

*barrido con el comando DC.

.DC V1 10.0 0.0 1.0

*Barrido DC de V1: desde 10 a 0 en pasos de a 1.

*Si se desea sólo un valor colocar iguales los límites inicial y final.

*Luego de lo anterior, pueden imprimirse resultados numéricos.

*Éstos quedan en archivo con extensión .out.

.PRINT DC V(1) V(2) V(1,2)

*Voltajes de nodos 1 y 2, Voltaje entre nodos 1 y 2.

.PRINT DC I(R1) I(V1) I(R2)

*I en R1, de 1 a 2. I en V1, de 1 a 0. I en R2, de 2 a 0.

*Con el comando PROBE se generan datos para generar formas

*de ondas. Se almacena en archivo con extensión .dat

.PROBE V(1) V(2) V(1,2)

.PROBE I(R1) I(V1) I(R2)

.END



Tablas generadas por el comando PRINT

V1 V(1) V(2) V(1,2)

1.000E+01 1.000E+01 8.889E+00 1.111E+00

9.000E+00 9.000E+00 8.444E+00 5.556E-01

8.000E+00 8.000E+00 8.000E+00 1.778E-11

7.000E+00 7.000E+00 7.556E+00 -5.556E-01

6.000E+00 6.000E+00 7.111E+00 -1.111E+00

5.000E+00 5.000E+00 6.667E+00 -1.667E+00

4.000E+00 4.000E+00 6.222E+00 -2.222E+00

3.000E+00 3.000E+00 5.778E+00 -2.778E+00

2.000E+00 2.000E+00 5.333E+00 -3.333E+00

1.000E+00 1.000E+00 4.889E+00 -3.889E+00

0.000E+00 0.000E+00 4.444E+00 -4.444E+00

V1 I(R1) I(V1) I(R2)

1.000E+01 2.222E-01 -2.222E-01 2.222E+00

9.000E+00 1.111E-01 -1.111E-01 2.111E+00

8.000E+00 3.556E-12 -3.556E-12 2.000E+00

7.000E+00 -1.111E-01 1.111E-01 1.889E+00

6.000E+00 -2.222E-01 2.222E-01 1.778E+00

5.000E+00 -3.333E-01 3.333E-01 1.667E+00

4.000E+00 -4.444E-01 4.444E-01 1.556E+00

3.000E+00 -5.556E-01 5.556E-01 1.444E+00

2.000E+00 -6.667E-01 6.667E-01 1.333E+00

1.000E+00 -7.778E-01 7.778E-01 1.222E+00

0.000E+00 -8.889E-01 8.889E-01 1.111E+00

Formas de ondas generadas por el comando PROBE.

Para ver las formas de ondas, deben agregarse trazas de las variables. Se agrega V(2), luego

en pestaña Plot, se agrega otro eje y de ordenadas, para las corrientes que se muestran en escala

diferente; y se agregan las trazas de I(R1), I(R2) y I(V1). Debe notarse que I(V1)=-I(R1).



Figura A1.2 Trazas.

El comando .OP calcula el punto de operación.

A1.3. Análisis transitorio. .tran

Se desea obtener la respuesta transitoria de la red de la Figura A1.3.

Figura A1.3 Red RLC paralelo

Se describe la red agregando condiciones iniciales a los elementos dinámicos.

Se emplea el comando .TRAN para efectuar una análisis transitorio. Deben especificarse: el

tiempo entre muestras, el tiempo final de la simulación, un retardo de toma de muestras al inicio

de la simulación, el máximo paso de integración en la simulación; al final se establece que use

condiciones iniciales.

En el ejemplo, si se divide el intervalo por el período entre muestras se obtiene el número de

puntos con que se genera la respuesta transitoria: 130ms/500us=260 muestras en el intervalo. La

u establece unidad de micro segundos.

El siguiente programa describe la red, y las condiciones iniciales.

1

L R C

0



Programa

Respuesta Natural de la red RLC paralelo, de la Figura A1.3.

R 0 1 1.0

L 0 1 8mH IC=10A

C 1 0 10mF IC=-2V

* muestreo t_final delay max_step UseInitialCondition

.TRAN 500us 130ms 0s 500us UIC

.PROBE V(1) I(C)

.END

Formas de ondas

Figura A1.4 Voltaje y corriente en el condensador.

A1.4. Análisis alterno. .AC

Determinar los voltajes V13 y V34, y la corriente en la red de la Figura A1.5.

Figura A1.5 Análisis alterno.

Se tienen los siguientes datos:

Vs(t) = 200sen(314t) [V];

V(1,3) V(3,0) I(C)

1 R1 2 3 4 R2 L C

Vs(t) +



R1=5[ ]; L=5/314 [Hy]; R2=4[ ]; C=1/1256 [F].

Las fuentes deben tener el tipo AC, y no es necesario indicar el ángulo de fase si éste es cero.

La magnitud se especifica en valores efectivos.

El comando .AC en modo barrido lineal LIN, establece el número de puntos, la frecuencia

inicial y final.

Para efectuar cálculos en estado estacionario se fija un punto con igual valor final e inicial

que la frecuencia en Hertz de las excitaciones. Con los datos de la red se tiene que la frecuencia

es de 50 Hertz.

Se emplea el comando .PRINT AC para especificar los voltajes y corrientes que desean

calcularse. Se agrega a las variables la letra M para determinar la magnitud, P para calcular el

ángulo de fase, R para obtener la parte real e I para la parte imaginaria.

En el programa se especifican sin unidades los valores reales de la inductancia y el

condensador, ya que éstas las asume por defecto.

Programa

Red con excitación de 50 Hz y en estado estacionario.

Vs 1 0 AC 141.423V 0

R1 1 2 5

L 2 3 0.015924

R2 3 4 4.0

C 4 0 7.962E-4

.AC LIN 1 50 50

.PRINT AC VM(1,3) VP(1,3) VM(3,0) VP(3,0) IM(C) IP(C)

.END

Resultados

Debe notarse que la solución “small signal bias solution” entrega valores nulos para los

voltajes, ya que la parte continua o DC es cero, debido a que no existen excitaciones constantes.

Se obtienen en el archivo .out, para el análisis alterno o AC, los siguientes valores:

FREQ = 5.000E+01

VM(1,3) = 1.105E+02

VP(1,3) = 3.864E+01

VM(3,0) = 8.832E+01

VP(3,0) = -5.136E+01

IM(C) = 1.562E+01

IP(C) = -6.370E+00

Es decir:



13

30

110,5 38,64º

88,32 51,36º

15,62 6,37º

V

V

I

Donde los módulos están en valores efectivos.

Si se desea obtener los valores de las formas de ondas, se determinan las transformaciones

inversas, obteniendo:

13

30

( ) 156,3sen(314 38,64º )

( ) 124,9sen(314 51,36º )

( ) 22,09sen(314 6,37º )

V t t

V t t

i t t

A1.5. Respuesta en frecuencia

Para estudiar el comportamiento en función de la frecuencia se dispone de un generador

sinusoidal de frecuencia variable. Estudiaremos la función de transferencia del filtro pasa

bajos que se muestra en la Figura A1.6.

Se desea calcular el cuociente entre la magnitud del voltaje de salida y la magnitud del voltaje

de entrada; también la diferencia entre el ángulo de fase del voltaje de salida menos el ángulo de

fase del voltaje de entrada.

Figura A1.6 Filtro pasa bajos.

El barrido en frecuencia se logra con el comando .AC, en el cual se coloca DEC para

describir un rango logarítmico. El número a continuación indica el número de puntos por

década, luego la mínima y máxima frecuencia.

En el programa se calculan 20 puntos por década en un rango de tres décadas que comienza

en 3 KHz.

Puede especificarse un barrido lineal, con el modo LIN. En este caso el primer valor indica

el número de puntos igualmente espaciados dentro del rango definido por su valor inicial y final.

Programa

Filtro pasa bajos

Vin 1 0 AC 1.0V

R 1 2 1

C 2 0 2E-6

R

C Vin

+

V(C)

I(R) 1 2

0



.AC DEC 20 3KHz 300kHz

.PROBE V(C)

.END

Resultados

Se obtiene un espectro de la amplitud del voltaje en el condensador, agregando una traza de

V(C).

Figura A1.7 Respuesta en frecuencia. Semilogarítmico.

Si antes de agregar la traza se escoge la función DB( ), y luego el voltaje del condensador, el

espectro queda con la ordenada en decibeles. El espectro se muestra en la Figura A1.8.

Se escogió módulo unitario para el voltaje de entrada, de esta manera, el voltaje en el

condensador es el módulo de la función de transferencia entre el voltaje de entrada y el de

salida. En caso de que no fuera unitario, debería efectuarse la traza de DB(V(C)/Vin).

Figura A1.8 Diagrama de Bode.



Puede determinarse la frecuencia para la cual la magnitud disminuye en tres decibeles,

respecto de la ganancia en frecuencias bajas, que se conoce como frecuencia de corte; y que la

pendiente para las frecuencias altas es de -20DB por década.

Si se agrega otro eje de ordenadas y se efectúa la traza de VP(C), se obtendrá la respuesta en

frecuencia de la función ángulo de fase del voltaje en el condensador. El ángulo se muestra, por

defecto, en grados.

Figura A1.9 Magnitud y ángulo.

A1.6. Fuentes controladas

A1.6.1. Fuentes controladas por voltaje

Figura A1.10 Fuente de voltaje controlada por voltaje.

Para definirla se coloca el nombre, que debe comenzar con E; luego el par de nodos entre los

cuales está ubicada la fuente controlada, primero el nodo asociado al polo positivo, luego el

asociado al polo negativo; después el par de nodos que definen la tensión de control y

finalmente la ganancia k. La fuente de la Figura A1.10 se define según:

En a b c d k

a

b

En k vc vc

c

d



De manera similar puede definirse una fuente de corriente controlada por voltaje. En este

caso la primera letra de la fuente debe ser G. El primer par de nodos define la dirección de la

corriente en la fuente controlada. Su dirección es del primer al segundo nodo.

A1.6.2. Fuentes controladas por corriente

Para especificar la corriente de control se coloca una fuente de voltaje independiente de valor

cero, en serie, con el elemento por el cual circula la corriente de control; esto se requiere, debido

a que entre un par de nodos pueden existir varios elementos en paralelo.

Este procedimiento también puede emplearse para especificar una medición de corriente

cuando se tienen varios elementos en paralelo. Para el caso de la Figura A1.11, la corriente que

circule desde c a d, se especificaría según: I(Vc).

El nombre de una fuente de corriente controlada por corriente debe comenzar con F.

Se requieren dos líneas para especificar la fuente controlada de la Figura A1.11.

Fn b a Vc k

Vc c d DC 0

Figura A1.11 Fuente controlada por corriente

La definición de una fuente de voltaje controlada por corriente es similar a la anterior, salvo

que la primera letra de esta fuente debe comenzar con la letra H.

Estas formas de fuentes controladas son las más simples que se pueden diseñar, SPICE

permite especificar fuentes controladas mediante: expresiones, polinomios, tablas y funciones

de transferencias. Ver la referencia o manual del usuario.

A1.6.3. Fuentes controladas por tabla

La descripción sintáctica, que aparece en el manual de referencia, del comando que permite

especificar una fuente controlada mediante una tabla es la siguiente.

E<name> <(+) <node> <(-) node> TABLE { <expression> } =

+ < <input value>,<output value> >*

Los símbolos entre paréntesis redondos son opcionales, los entre paréntesis de ángulo deben

ser reemplazados por el programador. Un símbolo + al inicio de una línea indica que es una

a

b

Fn=kic

ic

c

d

Vc



línea que continua el comando. El asterisco al final indica repetición de pares de valores

separados por comas.

La tabla de la Figura A1.12 se puede representar por dos puntos. Si el valor Vin excede el

rango definido, retorna el valor más cercano de Vout, esto se insinúa con los segmentos

horizontales. La tabla representa la ganancia de un amplificador operacional con saturación.

-10V

10V

-1mV

1mV

Vin

Vout

Figura A1.12 Tabla entrada-salida.

En la Figura A1.13 se describe una fuente de voltaje controlada por una función del voltaje

de control, cuya definición se muestra en la Figura A1.12.

Figura A1.13 Fuente controlada por tabla.

El siguiente comando describe los reemplazos por símbolos terminales en la definición

sintáctica anterior. Se han encerrado los pares de puntos entre paréntesis redondos para mejorar

la legibilidad.

ET a b TABLE {V(c,d)} = (-1mV,-10V) (1mV,10V)

Ejemplo A.1.

Para la red, de la Figura A1.14, considerar la estructura interna del amplificador operacional

que se muestra en la Figura A1.15, el que tiene su ganancia de voltaje definida por la

característica definida la Figura A1.12.

a

b

ET(Vc) Vc

c

d



Figura A1.14 Inversor con operacional.

En la Figura A1.15 la entrada inversora está asociada al nodo 2 y la no inversora al nodo 0,

ya que éste está conectado a tierra en la Figura A1.14. Una resistencia Ri de entrada del orden

de los 500 KOhms, es una aproximación de un circuito abierto; una resistencia Ro baja, del

orden de los 50 Ohms, es una aproximación de un generador ideal.

Figura A1.15 Amplificador Operacional.

Programa Ejemplo A.1

*Red externa al Amplificador

* no hay retardo ni amortiguamiento, ni desfase

Vi 1 0 SIN(0V 0.95V 10Hz 0 0 0)

Rg 1 2 5k

Rf 2 3 50k

Rc 3 0 10k

*Amplificador operacional con saturación

Ri 2 0 500k

Ro 4 3 50.0

Et 4 0 TABLE {V(0,2)}=(-1.0E-3,-10) (1.0E-3,10)

.TRAN 100us 200ms 0s 100us

.PROBE V(Vi) V(Rc)

.END

Para la fuente de tensión independiente se emplea un estímulo sinusoidal, el que se

programa mediante:

vo

Rg

vi

Rf

RC

1

2 3

0

ET Ri Vd

Ro 0 4 3

0 2



SIN (<ioff> <iampl> <freq> <td> <df> <phase>)

El primer argumento es el offset continuo, luego la amplitud, después la frecuencia; td es un

retardo, df es un factor de amortiguamiento, y finalmente el ángulo de fase en grados.

La forma de onda f(t) que se genera, queda descrita por:

( )

(2 / 360 ), ( )

(2 ( ( ) / 360 )) , t td df

ioff iampl sen phase t tdf t

ioff iampl sen freq t td phase e t td

Este estímulo genera sinusoides amortiguadas, después de un tiempo de retardo, y se emplea

en análisis transitorio. La Figura A1.16 muestra un seno desfasado y amortiguado.

Figura A1.16 SIN(2V 5V 2Hz 200ms 2 30d)

La Figura A1.17 muestra las formas de ondas del voltaje de entrada y de salida del

amplificador inversor que se muestra en la Figura A1.14.

Figura A1.17 Formas de ondas Ejemplo A.1.

Vi Vo

ke-2(t-td)

ioff

t-td td



A1.7. Subcircuitos

Una herramienta poderosa de SPICE es la que permite definir subcircuitos. Esta abstracción

es similar al uso de funciones en programación, permite definir un bloque de un circuito una

sola vez, y luego éste puede ser reutilizado.

En la definición del subcircuito se emplean como argumentos los nodos, usualmente en

forma simbólica. Es preciso definir el nombre del subcircuito y los identificadores de los nodos,

esto se muestra en la Figura A1.18.

El fin de la definición termina en .ENDS, que equivale al retorno de la función. Se ha

empleado un nodo interno int, que no aparece en la lista de argumentos formales.

Figura A1.18 Subcircuito AmpOp.

.SUBCKT AmpOp noinv inv out comun

Ri noinv inv 500k

Ro int out 50.0

Et int comun TABLE {V(noinv, inv)}=(-1mV,-10V) (1mV,10V)

.ENDS

El subcircuito debe ser definido antes de ser instanciado o invocado. El nombre del

subcircuito debe comenzar con X, y luego de la lista de nodos, en los que actualmente está

conectado, debe finalizar con el nombre del subcircuito.

El número de parámetros actuales debe ser igual al número de parámetros formales de la

definición.

Para el caso de la Figura A1.17:

XOp1 0 2 3 0 AmpOp

Figura A1.17 XOp1 es AmpOp.

ET Ri Vd

Ro noinv int out

comun inv

vo

Rg

vi

Rf

RC

1

2 3

0

XOp1



Ejemplo A.1 con subcircuito

*Definición del subcircuito

.SUBCKT AmpOp noinv inv out comun

Ri noinv inv 500k

Ro int out 50.0

Et int comun TABLE {V(noinv, inv)}=(-1mV,-10V) (1mV,10V)

.ENDS

*Red externa al Amplificador

Vi 1 0 SIN(0V 1.5V 10Hz 0 0 0);

Rg 1 2 5k

Rf 2 3 50k

Rc 3 0 10k

XOp1 0 2 3 0 AmpOp


.PROBE V(Vi) V(Rc)

.END

Ejemplo A.2.

La característica de un diodo puede representarse por una relación V(I) que puede describirse

como una fuente de voltaje controlada por corriente.

Figura A1.18 Diodo por tabla.

La relación no lineal, puede aproximarse por secciones lineales.

La siguiente tabla muestra que se tiene una corriente inversa de saturación muy pequeña, y

que el diodo comienza a conducir gradualmente.

Entrada I Salida V

-3 A -10V

-2 A -5V

-1 A -1 mV

125 mA 100 mV

V

I

ánodo

cátodo

V(I)

I



250 mA 150 mV

500 mA 200 mV

1,5 A 250 mV

3,5 A 300 mV

Para definir la corriente en el diodo se emplea una fuente continua de valor cero. De esta

manera la corriente puede especificarse como I(Vc).

La tabla está definida con la corriente como variable independiente, y el voltaje como salida.

En la Figura A1.19 se muestran los elementos y nodos empleados para definir una fuente de

voltaje controlada por corriente mediante una tabla o función.

Figura A1.19 Diodo definido por tabla.

.SUBCKT Diodo anodo catodo

Vc anodo int DC 0V;

Ed int catodo TABLE {I(Vc)}= (-3uA,-10V) (-2uA,-5V)

+(-1uA,-1mV) (0A,0V) (125mA,100mV) (250mA,150mV)

+ (500mA,200mV) (1.5A,250mV)(3.5A,300mV)

.ENDS

Después de definido el subcircuito podremos analizar redes que contengan diodos.

La Figura A1.20 ilustra un rectificador de media onda.

Figura A1.20 Rectificador de media onda.

Ed(I)

I(Vc)

cátodo

Vc=0

ánodo

int

Xd

0

Vs

2

+

1

V(2) RL



Rectificador de media onda

Vs 1 0 SIN(0V 6V 10Hz)

RL 2 0 5.0

Xd 1 2 Diodo; se asume definido previamente


.PROBE V(1,2) V(2)

.END

Figura A1.21 Voltajes en el diodo y en la carga.

Asumiendo definido el subcircuito previamente, el siguiente programa muestra la

característica del diodo.

Característica de diodo.

VIN 1 0

Xd 1 2 Diodo; se asume definido previamente

R 2 0 1E-5 ;se agrega resistencia de valor casi cero.

.DC VIN -10mV 300mV 10mV

.PROBE I(R)

.END



Figura A1.22 Característica de diodo.

A1.8. Modelos

Un modelo define la conducta eléctrica de una componente o parte.

Los modelos pueden especificarse mediante la descripción de subcircuitos expuesta antes, y

también mediante la especificación de los parámetros de componentes previamente definidas.

Existen modelos intrínsecos a SPICE, es decir modelos cuyas conductas están regidas por

ecuaciones que el programa tiene incorporadas. Dichas ecuaciones están basadas en leyes de la

física y pueden ajustarse mediante parámetros.

Como ejemplo, la siguiente ecuación relaciona los parámetros IS y N, con la corriente

normal I a través del diodo y su voltaje V entre terminales.

( ) ( 1)t

V

NV

t

I V IS e

kTV

q

El programa asume valores por defecto para los parámetros, y si el programador desea

cambiar un parámetro puede especificarlo indicando su valor, mediante el comando .model.

Para diodos se especifican los parámetros: IS la corriente de saturación, por defecto toma

valor 1E-14A; el coeficiente de emisión N, con valor por defecto 1; la resistencia serie RS, con

valor cero por defecto; la capacitancia de la juntura CJO, por defecto 0; el tiempo de tránsito

TT, por defecto 0; el voltaje inverso de ruptura BV, por defecto infinito; y la corriente inversa

de ruptura IBV, con valor por defecto 1E-10A.

Por ejemplo el siguiente comando model, define la lista de parámetros que tendrá el modelo de

nombre D1N4148. La letra D indica que el modelo es de diodos.



.model D1N4148 D

+ (IS=0.1PA, RS=16 CJO=2PF TT=12N BV=100 IBV=0.1PA)

Entonces la descripción de la red, de la Figura A1.20, empleando modelos intrínsecos de

diodos queda:

*Rectificador de media onda

Vs 1 0 SIN(0V 6V 10Hz)

RL 2 0 5.0

D1 1 2 D1N4148; nombre, ánodo cátodo, nombre modelo.

.model D1N4148 D

+(IS=0.1PA, RS=16 CJO=2PF TT=12N BV=100 IBV=0.1PA)


.PROBE V(1,2) V(2)

.END

Ejemplo A3.

Simular un transformador ideal para reducir el voltaje primario de 220V a 15 V.

Figura A1.23 Transformador ideal. Acoplamiento.

Rectificador con transformador casi ideal

Vs 3 0 SIN(0 220 50 0 0)

RL 4 0 500

Rs 3 1 10

L1 1 0 3450

L2 2 0 16

K1 L1 L2 0.99999 ; acoplamiento casi unitario

D1 2 4 mod1

.model mod1 D (IS=1e-14)

.tran 0.2m 20m

.Probe V(2), V(4)

.end

Las inductancias mutuas se especifican mediante el coeficiente de acoplamiento, que debe

comenzar con la letra K, y ubicado inmediatamente después de la definición de las

inductancias.

1

Vs V1

I(L1)

L1 V2

I(L2)

L2

M

0

2 4

V(4) RL

+

3

Rs

0

D1



Las marcas del acoplamiento se asocian con el primer nodo de cada inductancia, y las

corrientes I(L1) e I(L2), se asumen entrando por los puntos.

La relación entre las inductancias propias y mutua, y el coeficiente de acoplamiento K, está

dada por:

1 2M K L L

El valor de K debe ser mayor que cero y menor que uno; no es posible lograr acoplamiento

perfecto o unitario.

Un transformador ideal se simula con un valor del factor de acoplamiento lo más cercano

posible a uno, por ejemplo K=0.999999; y la razón de vueltas por la relación:

1 1

2 2

n L

n L

Esto debido a que las inductancias propias son proporcionales al cuadrado del número de

vueltas.

La condición de no tener pérdidas puede simularse logrando, para la frecuencia de trabajo,

que:

2 i ifL R

Para el ejemplo la condición anterior se cumple para la resistencia mayor con L2 igual a 16,

logrando un factor de 10. Para tener una reducción del voltaje primario de 220 a 15 volts, se

obtiene L1= 3450.

Figura A1.24 Voltajes en el secundario y en la carga.



SPICE dispone de modelos predefinidos para núcleos magnéticos, lo cual permite analizar

transformadores y ferritas.

Ejemplo A4.

Figura A1.25 Red con transistor

Amplificador en base a transistor bipolar.

Vin 1 0 ac 1 Rs 1 2 1 C1 2 3 100uf Rb 5 3 465k Rc 5 4 3k Vcc 5 0 dc 10 Q1 4 3 0 modelonpn

.model modelonpn npn (is=2e-15 bf=100 vaf=200)

.op ;calcula punto operación

*Respuesta en frecuencia

.ac dec 10 100 10k

.probe VM(1) VM(4) ; Ganancia=V(4)/V(1)

*plot ac VM(4) ;Tabla módulo salida

* Cálculo conductancia de entrada en pequeña señal (i/v)

.probe IM(Vin)

*.plot ac IM(Vin)

.end

E

Vcc

B

R c R

b

v in

R s

V(4)

C

C1

0

1 2

3

5

4

Q1



Figura A1.26 Ganancia y conductancia de entrada.

El comando OP calcula los valores de los voltajes de polarización, los que encuentran en el

archivo con extensión .out.

**** SMALL SIGNAL BIAS SOLUTION

V(1)=0.00 V(2)=0.00 V(3)=0,7146 V(4)=3,9136

V(5)=10

Además se muestra el consumo continuo de la fuente de polarización y la potencia entregada

por la fuente continua.

I(Vcc) -2.049E-03

TOTAL POWER DISSIPATION 2.05E-02 WATTS

I(Vc) de acuerdo al convenio de nombres de SPICE es la que entra por la polaridad positiva

de la fuente Vcc.

Se emplea un modelo de transistor npn, en el cual se especifican, con el nombre modelonpn,

tres parámetros; el resto de ellos se asumen por defecto.

BF es la ganancia de corriente en emisor común ß; IS es la corriente de saturación y VAF es

el voltaje Early.

Los valores por defecto son: BF= =100; IS=1E-16A, VAF=[infinito]. El modelo especifica

adicionalmente una serie de parámetros: las capacitancias de la juntura CJE (0pF) y CJC (0pF),

el tiempo de tránsito TT (0sec) y TR (0sec); las resistencias de base RB (0 Ohm), de emisor RE

(0 Ohm) y de colector RC (0 Ohm).

Una descripción completa del transistor 2N2222A NPN es la siguiente:

.model Q2N2222A NPN



+ (IS=14.34F XTI=3 EG=1.11 VAF=74.03 BF=255.9 NE=1.307 +ISE=14.34F IKF=.2847

XTB=1.5 BR=6.092 +NC=2 ISC=0 +IKR=0 RC=1 CJC=7.306P MJC=.3416 VJC=.75 FC=.5

+CJE=22.01P MJE=.377 VJE=.75 TR=46.91N TF=411.1P ITF=.6 +VTF=1.7 XTF=3 RB=10)

Ejemplo A5.

Para simular un dispositivo electrónico debe disponerse de un modelo. Si se dispone del

modelo en alguna biblioteca del simulador se lo emplea directamente. En caso de no tenerlo

puede buscarse en la red, mediante google. Por ejemplo: “mosfet model spice”.

Los modelos intrínsecos incorporan las ecuaciones de los dispositivos mediante parámetros

que el programador puede ajustar, para una mejor simulación con el dispositivo que luego se

empleará en el diseño o en el experimento de laboratorio.

Figura A1.27 Amplificador jfet.

Amplificador jfet fuente común “common source”

Vin 1 0 sin(0 1 50 0 0)

Vdd 3 0 dc 20

Rd 3 2 10k

Rs 4 0 1k

j1 2 1 4 J2N3819

.model J2N3819 njf ;

.tran 1m 30m

.probe v(2,0) v(1,0)

.end

* Los parámetros se derivan de las hojas de datos.

.model J2N3819 NJF

+(Beta=1.304m Betatce=-.5 Rd=1 Rs=1 Lambda=2.25m Vto=-3

+Vtotc=-2.5m Is=33.57f Isr=322.4f N=1 Nr=2 Xti=3 +Alpha=311.7u Vk=243.6 Cgd=1.6p

M=.3622 Pb=1 Fc=.5 +Cgs=2.414p Kf=9.882E-18 Af=1)

* National pid=50 case=TO92

Vdd

Rd

Vin

0

1

4

3

2 J1

Rs



* 88-08-01 rmn BVmin=25

Figura A1.28 Formas de ondas amplificador jfet.

Bibliotecas de modelos

Existen descripciones de modelos spice realizadas por los fabricantes de las componentes;

también existen varias empresas que venden bibliotecas de modelos.

Es importante conocer que en la red se pueden buscar modelos spice, ya que existe gran

cantidad de esta información.

Para facilitar la administración de parámetros de modelos intrínsecos y de los netlist de

subcircuitos existen aplicaciones que realizan este trabajo.

Además de los modelos intrínsecos que se han presentado en los ejemplos anteriores: diodos,

transistores bipolares, jfet, acoplamiento magnético, se disponen modelos para mosfet, líneas de

transmisión, y también para todo tipo de componentes digitales.

A1.9. Función de transferencia

El comando:

.TF <variable salida> <fuente de entrada>

Calcula mediante linealización respecto del punto de polarización la ganancia de pequeña

señal, obteniendo la función de transferencia o razón entre la variable de salida y entrada.

Determina la resistencia respecto de la fuente de entrada y la resistencia respecto de los

terminales de salida.

El comando genera la salida directamente al archivo de salida con extensión .out.

Si además se agrega el comando .op que calcula el punto de operación, la combinación de

comandos permite obtener el equivalente Thévenin.



Ejemplo A.5.

Se desea calcula la red Thévenin vista desde los terminales a-b, para la red de la Figura

A1.29.

Figura A1.29 Red Thévenin.

El comando .OP calcula todos los voltajes en los nodos. El voltaje de la fuente Thévenin

vista por terminales a-b es V(3), y es el valor de VT de la Figura A1.30.

El comando: .TF V(R4) Vs

Calcula el cuociente: V(R4)/Vs y las resistencias Rin y Rout que se ilustran en la Figura

A1.30

Figura A1.30 Resistencias en TF.

Para el siguiente programa, con los valores de resistencias que se indican:

Cálculo equivalente Thévenin

Vs 1 0 DC 10

R1 1 2 4

R2 2 0 4

R3 2 3 2

R4 3 0 4

.OP

.TF V(R4) Vs

.END

Resultan en el archivo de salida:

Vs

0

V(3) R4

+

1

R1

2 R3

R2

3 a

b

Vs

0

+

1

Rin

VT

0

V(3)

+

3

Rout a

b



NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 10.0000 ( 2) 3.7500 ( 3) 2.5000

V(R4)/Vs = 2.500E-01

INPUT RESISTANCE AT Vs = 6.400E+00

OUTPUT RESISTANCE AT V(R4) = 2.000E+00

Entonces:

Rin=6,4 Rout=2,0 Vt=2,5

Ejemplo A.6.

Para la red de la Figura A1.31 se puede determinar el equivalente Thévenin, pero deben

efectuarse cálculos en modo .DC y en modo .AC.

Figura A1.31 Red con fuente alterna y continua.

El voltaje continuo en la salida se calcula mediante el siguiente programa que emplea el

comando .OP y .TF para calcular la resistencia equivalente.

El voltaje alterno en la salida se calcula con el comando .AC para una sola frecuencia.

Cálculo equivalente Thévenin

Vcc 4 0 DC 10

* valor efectivo=1,06067 equivale a valor máximo=1.5

Vac 1 0 AC 1.06067 0

R1 1 2 4

R2 2 4 4

R3 2 3 2

R4 3 0 4

.OP

.TF V(R4) Vac

.AC LIN 1 10 10

.PRINT AC VM(R4) VP(R4)

.END

Vac

0

V(3) R4

+

1

R1

2 R3

R2

3 a

b

4

Vcc +

=



La parte continua entrega un voltaje de nodo 3 igual a 2,5 V; la resistencia Thévenin resulta

con valor 2.

El valor efectivo del voltaje de salida resulta VM(R4)= 0,265 lo que equivale a una amplitud

máxima de 0,374763.

Entonces la fuente Thévenin resulta:

VT = 2,5 + 0,375sen(2 10t)

Para visualizar los datos puede efectuarse un análisis transitorio mediante una excitación

sinusoidal equivalente, y generar las formas de ondas mediante el comando PROBE.

Formas de ondas. Análisis transitorio.

Vcc 4 0 DC 10

Vac 1 0 SIN(0V 1.5V 10Hz 0 0 0)

R1 1 2 4

R2 2 4 4

R3 2 3 2

R4 3 0 4

.TRAN 0 0.125 0

.PROBE V(R4) V(1)

.END

Figura A1.32 Formas de ondas Vac y V(R4).

Ejemplo A.7.

La determinación del equivalente Thévenin en redes con fuentes controladas, por métodos de

papel y lápiz, suele ser laborioso; el comando TF permite estos cálculos con facilidad.

Determinar el equivalente Thévenin, entre los terminales a y b, de la red de la Figura A1.33.



Figura A1.33 Thévenin con fuentes controladas.

Para definir la corriente de control es preciso agregar una fuente de tensión continua de valor

cero entre la resistencia R2 y tierra.

Cálculo equivalente Thévenin con fuentes controladas.

Vs 1 0 DC 10

R1 1 2 4

R2 2 4 4

R3 2 3 2

R4 3 0 4

Vdc 4 0 DC 0

F1 0 3 Vdc 1.5

.OP

.TF V(R4) Vs

.END

Resultan los siguientes voltajes de nodos:

V(2)=6 V(3) =7

La resistencia de salida resulta V(R4)=3,2

Figura A1.34 Red Thévenin de Figura A1.33.

i Vs

0

V(3) R4

+

1

R1

2 R3

R2

3 a

b

i

7

0

V(3)

+

3

3,2 a

b



A1.10. Fuentes en PSPICE

Estímulos transitorios

Además de las fuentes independientes DC y AC, que ya se han empleado, es posible usar

fuentes independientes con formas de ondas: exponenciales, sinusoidales, moduladas en

frecuencia, de pulsos, y definidas por segmentos lineales.

Puede mantenerse una biblioteca de estímulos, y se dispone de facilidades para mantenerlas.

Las fuentes controladas además de la definición por tabla, tienen muchas posibilidades

adicionales. Pueden emplearse polinomios, funciones, expresiones, funciones de transferencia

en transformada de Laplace.

El siguiente programa ilustra una señal tipo pulso, en el cual pueden definirse tiempos de

subida Tr y bajada Tf. Además puede definirse un retardo desde el inicio Td, el ancho y el

período.

Pulso

Respuesta transitoria a un pulso.

* V1 V2 Td Tr Tf Tw Período.

Vs 1 0 PULSE(0V 10V 0s 100ms 200ms 900ms 2s )

Rs 1 2 10k

Cs 2 0 100uF IC=3V ;T=RC=0,1 seg

.TRAN 5ms 5s 0s 5ms UIC

.PROBE

.END

Figura A1.35 Estímulo Pulso.

Estímulo por secciones lineales. PWL

Es uno de los estímulos más generales que pueden generarse.

El siguiente programa ilustra una forma de onda definida por cinco segmentos. Se expresan

como pares ordenados (tiempo, valor).



Respuesta transitoria a forma de onda definida por secciones.

Vs 1 0 PWL (0s, 1V) (1.2, 5) (1.4, 2) (2, 4) (3, 1)

Rs 1 2 10k



.PROBE

.END

Figura A1.36 Estímulo PWL.

Funciones de transferencia

Pueden analizarse filtros, y sistemas de control definidos por su función de transferencia.

Para lograr esto SPICE implementan fuentes controladas definidas por una función de

transferencia en transformada de Laplace.

La sintaxis para fuentes de voltaje controladas por voltaje es la siguiente:

E<name> <(+) node> <(-) node> LAPLACE { <expression> } =

+ { <transformada> }



Figura A1.37 Estímulo Laplace.

Para la Figura A1.37 se tiene:

Vs 1 0 AC 1V

En a b Laplace {V(1)}={1E3/(s+1E3)}

El voltaje en la fuente controlada es la transformada inversa de Laplace del producto de la

función de transferencia por la transformada de Laplace del voltaje de control. De esta forma se

reemplaza el circuito del filtro que realiza la misma función.

Pueden estudiarse respuestas en frecuencia mediante el comando AC, y formas de ondas

mediante análisis transitorios con el comando tran.

Respuesta en frecuencia usando fuente de Laplace

Vs 1 0 AC 1V

RS 1 0 1MEG

*Ef 2 0 Laplace { V(1) }=

+{(143.14)/(s^2+14.256*s+151.62)};Chebyshev

Ef 2 0 Laplace {V(1)}={100/(s^2+14.142*s+100)};Butterworth

Rl 2 0 1k

.AC DEC 20 0.1Hz 30Hz

.PROBE V(2)

.END

Figura A1.38 Respuesta en frecuencia. Laplace.

L-1

[H(s)Vc(s)] Vc

1

0

+ Vs

a

b

En Rs Rc



La frecuencia de corte está en 1 Hz.

Puede estudiarse la respuesta transitoria, introduciendo un estímulo en la pasa banda.

Respuesta transitoria usando fuente de Laplace

Vs 1 0 PULSE(0V 1V 0s 10ms 10ms 500ms 1s)

RS 1 0 1MEG

*Ef 2 0 Laplace { V(1) }=

*+{(143.14)/(s^2+14.256*s+151.62)};Chebyshev

Ef 2 0 Laplace { V(1) }=

+{100/(s^2+14.142*s+100)};Butterworth

Rl 2 0 10K

.TRAN 20ms 2s 0s 100ms

.PROBE V(2) V(1)

.END

Figura A1.39 Respuesta transitoria. Laplace.

A1.11. Fourier

El commando .FOUR realiza un análisis de Fourier de la respuesta transitoria.

.FOUR <frecuencia> [nº armónicas] <variable salida>

Se analizan los últimos (1/frecuencia) segundos de la respuesta transitoria. Por defecto

calcula hasta la novena armónica.

El resultado no se muestra gráficamente, sólo se dispone en el archivo de salida.

El estímulo es una sinusoide de frecuencia 2Hz, y se analiza el contenido armónico de la

respuesta con una frecuencia fundamental 2Hz, con el comando FOUR.

Análisis de Fourier de sinusoide pura con offset.

Vs 1 0 SIN(2V 5V 2Hz 0 0 0)

Rs 1 2 10k





.PROBE

.FOUR 2Hz 5 V(Vs)

.END

Resultados

Se muestran los resultados normalizados con respecto a la frecuencia fundamental, se aprecia

el fuerte contenido de la fundamental, y el valor continuo debido al offset del estímulo.

FOURIER COMPONENTS OF TRANSIENT RESPONSE V(Vs)

DC COMPONENT = 1.999524E+00

HARMONIC FREQ NORMALIZED NORMALIZED

NO (HZ) COMPONENT PHASE (DEG)

1 2.000E+00 1.000E+00 0.000E+00

2 4.000E+00 1.110E-04 1.026E+02

3 6.000E+00 2.944E-05 -1.560E+02

4 8.000E+00 1.293E-05 -5.304E+01

5 1.000E+01 7.346E-06 4.915E+01

TOTAL HARMONIC DISTORTION = 1.157892E-02 %

Transformada rápida de Fourier

En PSPICE se puede visualizar el espectro oprimiendo FFT en los paneles de herramientas.

Esto alterna entre formas de ondas y el espectro de amplitudes.

Para el siguiente análisis transitorio de un tren de pulsos, puede obtenerse la transformada

rápida de Fourier, que se muestra en la Figura A1.40.

Vs 1 0 PULSE(0V 1V 0s 10ms 10ms 50ms 500ms)

.TRAN 20ms 2s 0s 100ms

.PROBE V(1)

.END

Figura A1.40 FFT de Figura A1.30.



A1.12. Referencias

http://infopad.eecs.berkeley.edu/~icdesign/SPICE

Tutoriales:

William E. Dillon. Universidad de Texas.

http://dave.uta.edu/dillon/pspice/

Jan Van der Spiegel. Universidad de Pennsylvania.

http://www.seas.upenn.edu/~jan/spice/spice.overview.html

Reference Guide. PSpice. Orcad-Cadence.

Ecuaciones para modelar dispositivos electrónicos:

http://ece-www.colorado.edu/~bart/book/book/contents.htm



Índice general

APÉNDICE 1 .......................................................................................................................... 1

USO DE SPICE EN LA SIMULACIÓN DE REDES ......................................................... 1

A1.1 INTRODUCCIÓN ............................................................................................................ 1 A1.2. ANÁLISIS CONTINUO O DC. .OP .DC ........................................................................ 2

Programa .................................................................................................................................................... 3 Tablas generadas por el comando PRINT .................................................................................................. 4 Formas de ondas generadas por el comando PROBE. ............................................................................... 4

A1.3. Análisis transitorio. .tran ....................................................................................... 5 Programa .................................................................................................................................................... 6 Formas de ondas ........................................................................................................................................ 6

A1.4. Análisis alterno. .AC .............................................................................................. 6 Programa .................................................................................................................................................... 7 Resultados .................................................................................................................................................. 7

A1.5. Respuesta en frecuencia .......................................................................................... 8 Programa .................................................................................................................................................... 8 Resultados .................................................................................................................................................. 9

A1.6. Fuentes controladas .............................................................................................. 10 A1.6.1. Fuentes controladas por voltaje ................................................................................................... 10 A1.6.2. Fuentes controladas por corriente ................................................................................................ 11 A1.6.3. Fuentes controladas por tabla ...................................................................................................... 11

A1.7. Subcircuitos........................................................................................................... 15 Ejemplo A.2. ............................................................................................................................................ 16

A1.8. Modelos ................................................................................................................. 19 Ejemplo A3. ............................................................................................................................................. 20 Ejemplo A4. ............................................................................................................................................. 22 Ejemplo A5. ............................................................................................................................................. 24 Bibliotecas de modelos ............................................................................................................................ 25

A1.9. Función de transferencia ...................................................................................... 25 Ejemplo A.5. ............................................................................................................................................ 26 Ejemplo A.6. ............................................................................................................................................ 27 Ejemplo A.7. ............................................................................................................................................ 28

A1.10. Fuentes en PSPICE ............................................................................................. 30 Estímulos transitorios .............................................................................................................................. 30 Pulso ........................................................................................................................................................ 30 Estímulo por secciones lineales. PWL ..................................................................................................... 30 Funciones de transferencia ....................................................................................................................... 31

A1.11. Fourier ................................................................................................................ 33 Resultados ................................................................................................................................................ 34 Transformada rápida de Fourier ............................................................................................................... 34

A1.12. Referencias .......................................................................................................... 35 ÍNDICE GENERAL ................................................................................................................. 36



Índice de figuras.

Figura A1.1 Convenios SPICE ...................................................................................................... 2 Figura A1.2 Trazas. ....................................................................................................................... 5 Figura A1.3 Red RLC paralelo ...................................................................................................... 5 Figura A1.4 Voltaje y corriente en el condensador. ...................................................................... 6 Figura A1.5 Análisis alterno. ........................................................................................................ 6 Figura A1.6 Filtro pasa bajos. ....................................................................................................... 8 Figura A1.7 Respuesta en frecuencia. Semilogarítmico. .............................................................. 9 Figura A1.8 Diagrama de Bode. .................................................................................................... 9 Figura A1.9 Magnitud y ángulo. ................................................................................................. 10 Figura A1.10 Fuente de voltaje controlada por voltaje. .............................................................. 10 Figura A1.11 Fuente controlada por corriente ............................................................................ 11 Figura A1.12 Tabla entrada-salida. ............................................................................................ 12 Figura A1.13 Fuente controlada por tabla. .................................................................................. 12 Figura A1.14 Inversor con operacional. ...................................................................................... 13 Figura A1.15 Amplificador Operacional. .................................................................................... 13 Figura A1.16 SIN(2V 5V 2Hz 200ms 2 30d).............................................................................. 14 Figura A1.17 Formas de ondas Ejemplo A.1. ............................................................................. 14 Figura A1.18 Subcircuito AmpOp. ............................................................................................ 15 Figura A1.17 XOp1 es AmpOp. .................................................................................................. 15 Figura A1.18 Diodo por tabla. ..................................................................................................... 16 Figura A1.19 Diodo definido por tabla. ...................................................................................... 17 Figura A1.20 Rectificador de media onda. .................................................................................. 17 Figura A1.21 Voltajes en el diodo y en la carga. ........................................................................ 18 Figura A1.22 Característica de diodo. ......................................................................................... 19 Figura A1.23 Transformador ideal. Acoplamiento. .................................................................... 20 Figura A1.24 Voltajes en el secundario y en la carga. ................................................................ 21 Figura A1.25 Red con transistor .................................................................................................. 22 Figura A1.26 Ganancia y conductancia de entrada. .................................................................... 23 Figura A1.27 Amplificador jfet. .................................................................................................. 24 Figura A1.28 Formas de ondas amplificador jfet. ....................................................................... 25 Figura A1.29 Red Thévenin. ....................................................................................................... 26 Figura A1.30 Resistencias en TF. ............................................................................................... 26 Figura A1.31 Red con fuente alterna y continua. ........................................................................ 27 Figura A1.32 Formas de ondas Vac y V(R4). ............................................................................. 28 Figura A1.33 Thévenin con fuentes controladas. ........................................................................ 29 Figura A1.34 Red Thévenin de Figura A1.33. ............................................................................ 29 Figura A1.35 Estímulo Pulso. ..................................................................................................... 30 Figura A1.36 Estímulo PWL. ...................................................................................................... 31 Figura A1.37 Estímulo Laplace. .................................................................................................. 32 Figura A1.38 Respuesta en frecuencia. Laplace. ........................................................................ 32 Figura A1.39 Respuesta transitoria. Laplace. .............................................................................. 33 Figura A1.40 FFT de Figura A1.30. ............................................................................................ 34

uso de spice. - ramos departamento de...

Documents